iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion recupera(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recupera(n);
            coge-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        norte;
        repetir n veces inicio
            si junto-a-zumbador y orientado-al-norte entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-sur entonces inicio
            recupera(n);
        fin sino inicio
            si no junto-a-zumbador entonces este;
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            norte;
            avanza;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            deja-zumbador;
            sur;
            avanza;
            si junto-a-zumbador entonces inicio
                compara(n);
                si orientado-al-este entonces inicio
                    norte;
                    avanza;
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                fin sino inicio
                    norte;
                    avanza;
                    oeste;
                    mientras no orientado-al-sur hacer inicio
                        si junto-a-zumbador entonces coge-zumbador;
                        si frente-libre entonces inicio
                            avanza;
                        fin sino inicio
                            sur;
                            avanza;
                        fin;
                    fin;
                fin;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;

    define-nueva-instruccion toma(n) como inicio
        repetir n veces inicio
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
            este;
            si frente-libre entonces avanza;
        fin;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        este;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        mientras orientado-al-este hacer inicio
            coge-zumbador;
            sur;
            avanza;
            contar(0);
        fin;

    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si no orientado-al-oeste entonces inicio
            toma(n);
            cuenta(sucede(n));
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras orientado-al-oeste y frente-libre hacer inicio
                repetir precede(n) veces inicio
                    si frente-libre entonces inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        avanza;
                        si orientado-al-oeste entonces inicio
                            mientras junto-a-zumbador hacer coge-zumbador;
                        fin;
                    fin sino inicio
                        sur;
                    fin;
                fin;
            fin;
            si orientado-al-sur entonces inicio
                este;
                cuenta(sucede(n));
            fin;
            mientras frente-libre hacer avanza;
            sur;
            avanza;
            este;
            repetir precede(n) veces si frente-libre entonces avanza;
            mientras junto-a-zumbador y frente-libre hacer inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                avanza;
            fin;
            apagate;
        fin;
    fin;

    inicia-ejecucion
        cuenta(1);
        apagate;
    termina-ejecucion
finalizar-programa
