iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion marca (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            marca (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            sur;
            avanza;
            avanza;
            este;
            repetir precede (n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    oeste;
                    mientras frente-libre hacer
                        avanza;
                    sur;
                    avanza;
                    apagate;
                fin;
            fin;
            si frente-libre entonces inicio
                avanza;
                sur;
                avanza;
                si no-junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    oeste;
                    mientras frente-libre hacer
                        avanza;
                    sur;
                    avanza;
                    apagate;
                fin
                sino inicio
                    norte;
                    avanza;
                    este;
                fin;
            fin
            sino inicio
                oeste;
                mientras frente-libre hacer
                    avanza;
                sur;
                avanza;
                apagate;
            fin;
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
            este;
            mientras orientado-al-este hacer inicio
                sur;
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    este;
                    deja-zumbador;
                    repetir precede (n) veces inicio
                        si frente-libre entonces
                            avanza;
                    fin;
                    si frente-libre entonces
                        avanza;
                fin
                sino inicio
                    norte;
                    avanza;
                    oeste;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion compara (n) como inicio
        si junto-a-zumbador y no si-es-cero (n) entonces inicio
            coge-zumbador;
            compara (precede(n));
            deja-zumbador;
        fin
        sino inicio
            si junto-a-zumbador o no si-es-cero (n) entonces inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion revisa (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            revisa (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            norte;
            avanza;
            este;
            si frente-libre entonces
                avanza;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            sur;
            avanza;
            si junto-a-zumbador entonces inicio
                norte;
                avanza;
                este;
                mientras orientado-al-este hacer inicio
                    mientras frente-libre y no-junto-a-zumbador hacer
                        avanza;
                    sur;
                    avanza;
                    si junto-a-zumbador entonces inicio
                        compara (n);
                        si orientado-al-sur entonces inicio
                            norte;
                            avanza;
                            este;
                            coge-zumbador;
                            avanza;
                            si no-junto-a-zumbador entonces
                                deja-zumbador;
                            avanza;
                        fin
                        sino inicio
                            este;
                            mientras frente-libre hacer
                                avanza;
                            norte;
                            avanza;
                            oeste;
                            mientras frente-libre hacer inicio
                                mientras junto-a-zumbador hacer
                                    coge-zumbador;
                                avanza;
                            fin;
                            mientras junto-a-zumbador hacer
                                coge-zumbador;
                            norte;
                            avanza;
                            este;
                            mientras frente-libre y no-junto-a-zumbador hacer
                                avanza;
                            coge-zumbador;
                            oeste;
                            mientras frente-libre hacer
                                avanza;
                            norte;
                            avanza;
                            deja-zumbador;
                        fin;
                    fin
                    sino inicio
                        norte;
                        avanza;
                        oeste;
                        mientras frente-libre hacer
                            avanza;
                    fin;
                fin;
            fin
            sino inicio
                este;
                mientras frente-libre hacer
                    avanza;
                norte;
                avanza;
                oeste;
                mientras frente-libre hacer inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    avanza;
                fin;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                norte;
                avanza;
                este;
                mientras frente-libre y no-junto-a-zumbador hacer
                    avanza;
                coge-zumbador;
                oeste;
                mientras frente-libre hacer
                    avanza;
                norte;
                avanza;
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion checa como inicio
        mientras orientado-al-oeste hacer inicio
            este;
            mientras frente-libre y junto-a-zumbador hacer
                avanza;
            norte;
            avanza;
            si no-junto-a-zumbador entonces inicio
                sur;
                avanza;
                deja-zumbador;
                avanza;
                revisa (0);
                checa;
            fin
            sino inicio
                sur;
                avanza;
                avanza;
                este;
                mientras frente-libre hacer inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    si frente-libre entonces
                        avanza;
                fin;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                oeste;
                mientras frente-libre hacer
                    avanza;
                este;
                apagate;
            fin;
        fin;
    fin;
    define-nueva-instruccion proceso como inicio
        norte;
        avanza;
        avanza;
        avanza;
        deja-zumbador;
        mientras orientado-al-norte hacer inicio
            marca (0);
            mientras frente-libre hacer
                avanza;
            checa;
        fin;
    fin;
    inicia-ejecucion
        proceso;
        apagate;
    termina-ejecucion
finalizar-programa