iniciar-programa
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion checa  como inicio
        si frente-libre y no-junto-a-zumbador entonces inicio
            avanza;
            checa;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
            fin sino avanza;
        fin sino repetir 2 veces gira-izquierda;
    fin;

    define-nueva-instruccion cuenta2(n) como inicio
        si frente-libre y no-junto-a-zumbador entonces inicio
            avanza;
            cuenta2(sucede(n));
        fin sino inicio
            si junto-a-zumbador entonces apagate;
            repetir n veces deja-zumbador;
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino inicio
            si orientado-al-este entonces inicio
                sur;
                repetir 2 veces deja-zumbador;
                avanza;
                cuenta2(0);
                este;
                avanza;
                mientras no-junto-a-zumbador hacer avanza;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    repetir 2 veces gira-izquierda;
                    avanza;
                    mientras no-junto-a-zumbador hacer avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    apagate;
                fin;
                repetir n veces deja-zumbador;
                repetir 2 veces coge-zumbador;
            fin sino inicio
                sur;
                repetir 2 veces deja-zumbador;
                avanza;
                cuenta2(0);
                oeste;
                avanza;
                mientras no-junto-a-zumbador hacer avanza;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    repetir 2 veces gira-izquierda;
                    avanza;
                    mientras no-junto-a-zumbador hacer avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    apagate;
                fin;
                repetir n veces deja-zumbador;
                repetir 2 veces coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta3(n) como inicio
        si junto-a-zumbador entonces inicio
            avanza;
            cuenta3(sucede(n));
        fin sino inicio
            sur;
            mientras frente-libre hacer avanza;
            este;
            avanza;
            si junto-a-zumbador entonces inicio
                norte;
                avanza;
                repetir n veces deja-zumbador;
                coge-zumbador;
            fin sino inicio
                oeste;
                repetir 2 veces avanza;
                norte;
                avanza;
                repetir n veces deja-zumbador;
                coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion trae(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            trae(sucede(n));
        fin sino inicio
            repetir 2 veces gira-izquierda;
            mientras no-junto-a-zumbador hacer avanza;
            norte;
            cuenta3(0);
            avanza;
            repetir n veces deja-zumbador;
            sur;
            avanza;
        fin;
    fin;

    define-nueva-instruccion deja(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            deja(n);
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion multiplica(n) como inicio
        si junto-a-zumbador  entonces inicio
            coge-zumbador;
            multiplica(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            avanza;
            deja(n);
        fin;
    fin;

    define-nueva-instruccion resta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta(sucede(n));
        fin sino inicio
            avanza;
            repetir n veces coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion divide(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            divide(sucede(n));
        fin sino inicio
            sur;
            repetir 2 veces avanza;
            mientras junto-a-zumbador hacer inicio
                repetir n veces coge-zumbador;
                norte;
                avanza;
                deja-zumbador;
                sur;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion sombra(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sombra(sucede(n));
        fin sino inicio
            avanza;
            este;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces inicio
                    oeste;avanza;este;
                    repetir n veces inicio
                        deja-zumbador;
                        si frente-libre entonces avanza;
                    fin;
                fin sino inicio
                    repetir 2 veces gira-izquierda;
                    avanza;
                    repetir n veces inicio
                        deja-zumbador;
                        si frente-libre entonces avanza;
                    fin;
                fin;
            fin sino inicio
                repetir n veces inicio
                    deja-zumbador;
                    si frente-libre entonces avanza;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras no-junto-a-zumbador hacer avanza;
        norte;
        mientras junto-a-zumbador hacer avanzA;
        este;
        mientras no-junto-a-zumbador hacer inicio
            repetir 2 veces inicio
                si no-junto-a-zumbador entonces checa;
            fin;
            si no-junto-a-zumbador entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                fin sino apagate;
                este;
            fin;
        fin;
        cuenta(0);
        repetir 2 veces gira-izquierda;
        repetir 2 veces avanza;
        mientras no-junto-a-zumbador hacer avanza;
        trae(0);
        multiplica(0);
        norte;
        avanza;
        resta(0);
        divide(0);
        norte;
        avanza;
        sur;
        sombra(0);
        apagate;
    termina-ejecucion
finalizar-programa
