iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion sol(n) como inicio
        si no-junto-a-zumbador entonces inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si frente-bloqueado y no-junto-a-zumbador entonces inicio
                si orientado-al-este entonces inicio
                    gira(1);
                    si frente-libre entonces avanza;
                    gira(1);
                fin sino inicio
                    gira(3);
                    si frente-libre entonces avanza;
                    gira(3);
                fin;
                sol(sucede(n));
                sal-de-instruccion;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            repetir precede(n) veces avanza;
            repetir n veces deja-zumbador;
            avanza;
        fin;
    fin;
    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                apagate;
            fin sino deja-zumbador;
            avanza;
            contar(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(1);
            mientras frente-libre hacer avanza;
            gira(2);
            sol(2);
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion encuentra como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        si frente-libre entonces inicio
            avanza;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si junto-a-zumbador entonces sal-de-instruccion;
        fin;
        gira(2);
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si frente-libre entonces avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;
    define-nueva-instruccion sombra-oeste(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sombra-oeste(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira(3);
            mientras no-junto-a-zumbador hacer avanza;
            repetir n veces inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion sombra-este(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sombra-este(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            gira(1);
            mientras no-junto-a-zumbador hacer avanza;
            repetir n veces inicio
                si no-junto-a-zumbador entonces deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion segundo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            segundo(n);
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion multiplicacion(n) como inicio
        si no-junto-a-zumbador entonces inicio
            avanza;
            multiplicacion(sucede(n));
            sal-de-instruccion;
        fin;
        si junto-a-zumbador entonces inicio
            si orientado-al-oeste entonces inicio
                gira(1);
                avanza;
            fin sino inicio
                gira(3);
                avanza;
            fin;
            segundo(n);
        fin;
    fin;
    define-nueva-instruccion recoger(n) como inicio
        si junto-a-zumbador entonces inicio
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador sino sal-de-instruccion;
            fin;
            recoger(n);
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion division(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            division(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            avanza;
            recoger(n);
        fin;
    fin;
inicia-ejecucion
    mientras no-orientado-al-este hacer gira-izquierda;
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    gira(1);
    contar(0);
    gira(2);
    avanza;
    encuentra;
    si orientado-al-oeste entonces inicio
        gira(2);
        si frente-libre entonces avanza;
        multiplicacion(2);
        gira(2);
        avanza;
        division(0);
        sombra-oeste(0);
    fin sino inicio
        gira(2);
        si frente-libre entonces avanza;
        multiplicacion(2);
        gira(2);
        avanza;
        division(0);
        sombra-este(0);
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
