iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion mitad como inicio
        si junto-a-zumbador entonces inicio
            repetir 2 veces
                coge-zumbador;
            mitad;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion baja como inicio
        sur;
        mientras orientado-al-sur hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    avanza;
                fin
                sino inicio
                    deja-zumbador;
                    norte;
                    avanza;
                    este;
                fin;
            fin
            sino inicio
                avanza;
            fin;
        fin;
        mientras orientado-al-este hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    avanza;
                fin
                sino inicio
                    deja-zumbador;
                    oeste;
                    avanza;
                fin;
            fin
            sino inicio
                avanza;
            fin;
        fin;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        este;
        avanza;
        norte;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        sur;
        avanza;
        este;
    fin;
    define-nueva-instruccion sube como inicio
        este;
        mientras orientado-al-este hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    avanza;
                fin
                sino inicio
                    deja-zumbador;
                    oeste;
                    avanza;
                    sur;
                fin;
            fin
            sino inicio
                avanza;
            fin;
        fin;
        mientras orientado-al-sur hacer inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    avanza;
                fin
                sino inicio
                    deja-zumbador;
                    norte;
                    avanza;
                fin;
            fin
            sino inicio
                avanza;
            fin;
        fin;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        sur;
        avanza;
        oeste;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        este;
        avanza;
    fin;
    define-nueva-instruccion proceso como inicio
        sur;
        avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                norte;
                avanza;
                este;
                mitad;
                apagate;
            fin
            sino inicio
                norte;
                deja-zumbador;
                avanza;
                este;
            fin;
        fin
        sino inicio
            norte;
            avanza;
            este;
        fin;
        baja;
        sube;
        sur;
        avanza;
        este;
        avanza;
        sur;
        avanza;
        este;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        proceso;
    fin;
    inicia-ejecucion
        proceso;
        apagate;
    termina-ejecucion
finalizar-programa