iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion buscar_nueva_esquina_sup_der como inicio
    si izquierda-libre o frente-libre entonces inicio
        si izquierda-libre entonces inicio
            gira-izquierda;
            avanza;
            gira(3);
        fin;
        si frente-libre entonces avanza;
        buscar_nueva_esquina_sup_der;
        gira-izquierda;
        avanza;
        gira(3);
        avanza;
    fin;
    si orientado-al-oeste entonces gira(2);
fin;

define-nueva-instruccion llenar_cuadrado como inicio
    mientras orientado-al-oeste hacer inicio
        mientras orientado-al-oeste hacer inicio
            si no-junto-a-zumbador entonces repetir 2 veces deja-zumbador;
            si frente-libre entonces inicio avanza;
            fin sino gira(2);
        fin;
        si derecha-libre entonces inicio
            mientras frente-libre y junto-a-zumbador hacer avanza;
            repetir 2 veces inicio
               gira(3);
               avanza;
            fin
        fin;
    fin;
fin;

define-nueva-instruccion siguiente_linea como inicio
    si orientado-al-norte entonces inicio
        gira(2);
        avanza;
        gira-izquierda;
    fin;
    mientras derecha-libre y frente-libre y junto-a-zumbador hacer inicio
        avanza;
        gira(3);
        avanza;
        gira-izquierda;
    fin;
    si no-junto-a-zumbador entonces inicio
        gira(2);
        avanza;
    fin;
    si orientado-al-este y no-junto-a-zumbador entonces inicio
        gira(3);
        avanza;
    fin;
fin;

define-nueva-instruccion posicionarse como inicio
    si frente-libre entonces inicio
        avanza;
        posicionarse;
        si orientado-al-oeste entonces inicio
            gira(2);
            avanza;
        fin sino inicio
            repetir 2 veces avanza;
        fin;
        gira(1);
        avanza;
        gira(3);
    fin;
fin;

define-nueva-instruccion recordar_y_sembrar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recordar_y_sembrar(2);
        fin sino recordar_y_sembrar(1);
    fin sino inicio
        repetir a veces deja-zumbador;
        si frente-libre entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                recordar_y_sembrar(0);
            fin sino inicio
                si no (orientado-al-norte y izquierda-bloqueada) entonces inicio
                    si orientado-al-este entonces inicio
                        repetir 2 veces inicio
                            gira(1);
                            avanza;
                        fin;
                    fin;
                    siguiente_linea;
                    si junto-a-zumbador entonces inicio
                        recordar_y_sembrar(0);
                    fin sino inicio
                        gira(3);
                        posicionarse;
                        gira(2);
                    fin;
                fin sino inicio
                    gira(2);
                    avanza;
                    recordar_y_sembrar(0);
                fin;
            fin;
        fin sino inicio
            si orientado-al-sur entonces gira-izquierda;
            gira(2);
            siguiente_linea;
            si orientado-al-oeste entonces gira-izquierda;
            gira-izquierda;
            recordar_y_sembrar(0);
        fin;
        
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces coge-zumbador;
        fin;
        repetir a veces deja-zumbador;
        si frente-bloqueado entonces inicio
            gira(2);
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio coge-zumbador;
                fin sino deja-zumbador;
                avanza;
            fin;
            si derecha-libre entonces inicio
                repetir 2 veces inicio
                    gira(3);
                    avanza;
                fin;
            fin;
        fin sino avanza;
    fin;
fin;

    inicia-ejecucion

    mientras no-orientado-al-oeste hacer gira-izquierda;
    buscar_nueva_esquina_sup_der;
    gira(2);
    llenar_cuadrado;
    repetir 2 veces inicio
        gira(1);
        mientras junto-a-zumbador hacer avanza;
        gira(2);
        avanza;
    fin;
    recordar_y_sembrar(0);

        apagate;
    termina-ejecucion
finalizar-programa
