iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            si orientado-al-este y izquierda-libre entonces inicio
                gira(1);
                repetir 2 veces avanza;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion derecha como inicio
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
        si junto-a-zumbador entonces inicio
            gira(2);
            avanza;
        fin;
    fin;
    define-nueva-instruccion volver como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        repetir 2 veces avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(1);
    fin;
    define-nueva-instruccion division(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                division(sucede(n));
                sal-de-instruccion;
            fin sino inicio
                repetir n veces deja-zumbador;
                avanza;
                deja-zumbador;
            fin;
        fin sino inicio
            repetir n veces deja-zumbador;
            avanza;
        fin;
    fin;
    define-nueva-instruccion binario como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            derecha;
            repetir 2 veces deja-zumbador;
        fin sino inicio
            derecha;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion pasar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                si frente-libre entonces avanza;
                pasar;
                deja-zumbador;
                si frente-libre entonces avanza;
                sal-de-instruccion;
            fin sino inicio
                coge-zumbador;
                si frente-libre entonces avanza;
                pasar;
                repetir 2 veces deja-zumbador;
                si frente-libre entonces avanza;
                sal-de-instruccion;
            fin;
        fin sino inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(3);
            mientras frente-libre hacer avanza;
            gira(3);
            mientras frente-libre hacer avanza;
            gira(2);
        fin;
    fin;
inicia-ejecucion
    mientras no-orientado-al-este hacer gira-izquierda;
    si no-junto-a-zumbador entonces inicio
        mientras derecha-bloqueada hacer avanza;
        gira(3);
        avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
        si frente-libre entonces avanza;
        repetir 2 veces deja-zumbador;
        apagate;
    fin;
    mover;
    gira(2);
    mientras junto-a-zumbador hacer inicio
        division(0);
        binario;
        volver;
    fin;
    mientras frente-libre hacer avanza;
    gira(1);
    mientras frente-libre hacer avanza;
    gira(2);
    pasar;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(2);
    mientras junto-a-zumbador y frente-libre hacer inicio
        si junto-a-zumbador entonces coge-zumbador;
        si frente-libre entonces avanza;
    fin;
    repetir 2 veces deja-zumbador;
    si frente-libre entonces avanza;
        apagate;
    termina-ejecucion
finalizar-programa
