iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion mitad como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                mitad;
                deja-zumbador;
            fin sino inicio
                deja-zumbador;
                este;
                avanza;
            fin;
        fin sino inicio
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge(sucede(n));
        fin sino inicio
            si si-es-cero (precede(precede(n))) entonces inicio
                este;
                mientras derecha-bloqueada hacer avanza;
                sur;
                avanza;
                oeste;
                mientras frente-libre hacer avanza;
            fin;
            si frente-libre entonces inicio
                avanza;
                recoge(0);
            fin sino inicio
                este;
            fin;
            si no si-es-cero(precede(precede(n))) entonces inicio
                repetir n veces deja-zumbador;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        si no junto-a-zumbador entonces inicio
            mientras derecha-bloqueada hacer avanza;
            sur;
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            avanza;
            repetir 2 veces deja-zumbador;
            apagate;
        fin;
        mientras junto-a-zumbador hacer mitad;
        repetir 2 veces deja-zumbador;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        recoge(0);
        repetir 2 veces deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa

