iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion paridad(num) como inicio
        si no( si-es-cero(precede(num)) o si-es-cero(num) ) entonces inicio
            paridad(precede(precede(num)));
            deja-zumbador;
        fin sino inicio
            si si-es-cero(precede(num)) entonces deja-zumbador;
            avanza;
        fin;
    fin;

    define-nueva-instruccion digital(num) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            digital(sucede(num));
        fin sino inicio
            paridad(num);
        fin;
    fin;

    define-nueva-instruccion bajar como inicio
        mientras derecha-bloqueada hacer avanza;
        gira(3);
        avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;

    define-nueva-instruccion resultado como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                bajar;
            fin sino inicio
                avanza;
                resultado;
                deja-zumbador;
                avanza;
            fin;
        fin sino inicio
            avanza;
            resultado;
            avanza;
        fin;                
    fin;

    inicia-ejecucion
        mientras no-orientado-al-este hacer gira-izquierda;
        si no-junto-a-zumbador entonces inicio
            bajar;
            avanza;
        fin;
        mientras junto-a-zumbador y orientado-al-este hacer inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                digital(0);
            fin sino inicio
                deja-zumbador;
                avanza;
                repetir 2 veces deja-zumbador;
                gira(2);
                mientras frente-libre hacer avanza;
                gira(2);
                resultado;
            fin;
        fin;
        repetir 2 veces deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
