iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion corre como inicio
        mientras frente-libre hacer avanza;
    fin;
    define-nueva-instruccion llega como inicio
        mientras no-junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
                corre;
                norte;
                avanza;
                este;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuentaB(x) como inicio
        si junto-a-zumbador y no-orientado-al-oeste entonces inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
            cuentaB(sucede(x));
        fin sino inicio
            oeste;
            corre;
            sur;
            corre;
            este;
            avanza;
            si junto-a-zumbador entonces coge-zumbador;
            repetir x veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cuentaH(x) como inicio
        si junto-a-zumbador y no-orientado-al-sur entonces inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
            fin;
            cuentaH(sucede(x));
        fin sino inicio
            sur;
            si no-junto-a-zumbador entonces avanza;
            este;
            cuentaB(0);
            oeste;
            avanza;
            si junto-a-zumbador entonces coge-zumbador;
            repetir x veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion limpia como inicio
        repetir 2 veces avanza;
        si junto-a-zumbador entonces coge-zumbador;
        oeste;
        repetir 2 veces avanza;
    fin;
    define-nueva-instruccion por5(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            por5(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            este;
            repetir 2 veces avanza;
            repetir precede(x) veces repetir 5 veces deja-zumbador;
            oeste;
            avanza;
        fin;
    fin;
    define-nueva-instruccion por1(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            por1(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            este;
            avanza;
            repetir precede(x) veces deja-zumbador;
            oeste;
            repetir 2 veces avanza;
        fin;
    fin;
    define-nueva-instruccion mixta2(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mixta2(x);
            repetir x veces deja-zumbador;
        fin sino inicio
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion mixta(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mixta(sucede(sucede(sucede(sucede(x)))));
        fin sino inicio
            este;
            avanza;
            repetir 2 veces si junto-a-zumbador entonces coge-zumbador;
            mixta2(x);
        fin;
    fin;
    define-nueva-instruccion copia como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            copia;
            deja-zumbador;
        fin sino inicio
            oeste;
            corre;
        fin;
    fin;
    inicia-ejecucion
        oeste;
        corre;
        sur;
        corre;
        este;
        llega;
        norte;
        cuentaH(0);
        este;
        limpia;
        por5(0);
        por1(0);
        este;
        coge-zumbador;
        mixta(0);
        copia;
        apagate;
    termina-ejecucion
finalizar-programa
