iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion ubi como inicio
        ir11;
        mientras no junto-a-zumbador hacer inicio
            este;
            mientras frente-libre y no junto-a-zumbador hacer avanza;
            si no junto-a-zumbador entonces inicio
                oeste;
                mientras frente-libre hacer avanzA;
                norte;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion revisa como inicio
        este;
        coge-zumbador;
        repetir 2 veces inicio
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        si junto-a-zumbador entonces inicio
                            repetir 2 veces gira-izquierda;
                            avanza;
                            repetir 3 veces gira-izquierda;
                            avanza;
                            deja-zumbador;
                        fin sino inicio
                            repetir 2 veces gira-izquierda;
                            avanza;
                            repetir 3 veces gira-izquierda;
                            avanza;
                        fin;
                    fin sino inicio
                        gira-izquierda;
                        avanza;
                    fin;
                    deja-zumbador;
                fin sino inicio
                    repetir 2 veces gira-izquierda;
                    avanza;
                fin;
            fin sino inicio
                repetir 2 veces gira-izquierda;
            fin;
        fin;
        este;
    fin;

    define-nueva-instruccion cambia como inicio
        oeste;
        si frente-libre entonces avanzA;
        norte;
        si frente-libre entonces inicio
            avanza;
            oeste;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            repetir 2 veces gira-izquierda;
            si no junto-a-zumbador entonces avanza;
        fin;
    fin;

    define-nueva-instruccion marca(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            marca(sucede(n));
        fin sino inicio
            si frente-libre entonces avanza;
            si no junto-a-zumbador entonces cambia;
            si junto-a-zumbador entonces inicio
                revisa;
                marca(0);
            fin sino inicio
                ir11;
            fin;
            repetir n veces deja-zumbador;
        fin;
    fin;

    inicia-ejecucion
        ubi;
        revisa;
        marca(0);
        apagate;
    termina-ejecucion
finalizar-programa
