iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        este;
    fin;
    define-nueva-instruccion busca como inicio
        mientras no-junto-a-zumbador hacer inicio
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si no-junto-a-zumbador entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                    mientras frente-libre hacer
                        avanza;
                    este;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion otro como inicio
        si junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                otro;
                deja-zumbador;
            fin
            sino inicio
                orienta;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                deja-zumbador;
            fin;
        fin
        sino inicio
            orienta;
            mientras junto-a-zumbador hacer
                coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion lados como inicio
        si junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                lados;
                deja-zumbador;
            fin
            sino inicio
                orienta;
                busca;
                norte;
                otro;
                este;
                avanza;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                deja-zumbador;
            fin;
        fin
        sino inicio
            orienta;
            busca;
            norte;
            otro;
            este;
            avanza;
            mientras junto-a-zumbador hacer
                coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            repetir 2 veces
                deja-zumbador;
            oeste;
            avanza;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                norte;
                avanza;
                deja-zumbador;
                avanza;
                repetir n veces
                    deja-zumbador;
                sur;
                avanza;
                avanza;
            fin;
            norte;
            avanza;
            avanza;
            repetir n veces
                coge-zumbador;
            sur;
            avanza;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
                sur;
                avanza;
                deja-zumbador;
                norte;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion porcuatro (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            porcuatro (sucede(n));
        fin
        sino inicio
            avanza;
            repetir 4 veces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
        orienta;
    fin;
    define-nueva-instruccion portres (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            portres (sucede(n));
        fin
        sino inicio
            norte;
            avanza;
            avanza;
            avanza;
            repetir precede (n) veces inicio
                repetir 3 veces inicio
                    deja-zumbador;
                fin;
            fin;
            repetir precede (n) veces inicio
                repetir 2 veces inicio
                    deja-zumbador;
                fin;
            fin;
            sur;
            avanza;
            avanza;
            avanza;
        fin;
    fin;
    define-nueva-instruccion total (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            total (sucede(n));
        fin
        sino inicio
            orienta;
            repetir n veces
                deja-zumbador;
            apagate;
        fin;
    fin;
    define-nueva-instruccion top (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            top (sucede(n));
        fin
        sino inicio
            norte;
            avanza;
            avanza;
            avanza;
            oeste;
            avanza;
            repetir precede (n) veces
                deja-zumbador;
            total (0);
        fin;
    fin;
    define-nueva-instruccion normal como inicio
        repetir 2 veces
            coge-zumbador;
        cuenta (0);
        avanza;
        porcuatro (0);
        portres (0);
        este;
        avanza;
        top (0);
    fin;
    define-nueva-instruccion calcula como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            repetir 2 veces
                                deja-zumbador;
                            normal;
                        fin
                        sino inicio
                            repetir 2 veces
                                deja-zumbador;
                            oeste;
                            avanza;
                            portres (0);
                            este;
                            avanza;
                            top (0);
                        fin;
                    fin
                    sino inicio
                        oeste;
                        avanza;
                        este;
                        coge-zumbador;
                        apagate;
                    fin;
                fin
                sino inicio
                    oeste;
                    avanza;
                    este;
                fin;
            fin
            sino inicio
                este;
                avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        mientras junto-a-zumbador hacer inicio
                            coge-zumbador;
                            oeste;
                            avanza;
                            deja-zumbador;
                            este;
                            avanza;
                        fin;
                        oeste;
                        avanza;
                        este;
                        apagate;
                    fin
                    sino inicio
                        oeste;
                        avanza;
                        este;
                        deja-zumbador;
                        apagate;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion saludos como inicio
        orienta;
        busca;
        lados;
        orienta;
        calcula;
    fin;
    inicia-ejecucion
        saludos;
        apagate;
    termina-ejecucion
finalizar-programa