iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion deja(n) como repetir n veces deja-zumbador;
    define-nueva-instruccion casilla como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja(2);
                    apagate;
                fin sino deja(2);
            fin sino deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion columna como inicio
        mientras frente-libre hacer inicio
            casilla;
            avanza;
        fin;
        casilla;
    fin;
    define-nueva-instruccion busca como inicio
        mientras derecha-libre hacer inicio
            columna;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            avanza;
            gira(1);
        fin;
        columna;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(3);
        busca;
        apagate;
    termina-ejecucion
finalizar-programa
