iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion verifica como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    repetir 2 veces deja-zumbador;
                    apagate;
                fin
                sino repetir 2 veces deja-zumbador;
            fin
            sino deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion camina como inicio
        mientras frente-libre hacer inicio
            verifica;
            avanza;
        fin;
        verifica;
    fin;

    define-nueva-instruccion vuelta como inicio
        si orientado-al-norte entonces inicio
            gira(3);
            avanza;
            gira(3);
        fin
        sino inicio
            gira(1);
            avanza;
            gira(1);
        fin;
    fin;

    define-nueva-instruccion novia como inicio
        camina;
        vuelta;
    fin;

    inicia-ejecucion
        mientras no orientado-al-oeste hacer gira(1);
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
        mientras orientado-al-norte o orientado-al-sur hacer
            novia;
        apagate;
    termina-ejecucion
finalizar-programa
