iniciar-programa
    define-nueva-instruccion derecha como inicio
        repetir 3 veces gira-izquierda;
    fin;

    define-nueva-instruccion posicionar como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        derecha;
        mientras frente-libre hacer avanza;
        derecha;
    fin;

    define-nueva-instruccion cambiarFila como inicio
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        avanza;
        gira-izquierda;
    fin;

    define-nueva-instruccion comparar como inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                repetir 2 veces deja-zumbador;
                apagate; (*Karel encontro a su novia*)
            fin sino inicio
                repetir 2 veces deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    cambiarFila;
                fin;
            fin;
        fin sino inicio
            deja-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                cambiarFila;
            fin;
        fin;
    fin;

    define-nueva-instruccion buscar como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            comparar;
        fin sino inicio
            cambiarFila;
        fin;
    fin;

    inicia-ejecucion
        posicionar;
        mientras orientado-al-norte hacer buscar;
        apagate;
    termina-ejecucion
finalizar-programa
