iniciar-programa

define-nueva-instruccion situakarel como inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    repetir 3 veces gira-izquierda;
    mientras frente-libre hacer avanza;
    repetir 3 veces gira-izquierda;
fin;

define-nueva-instruccion mide-mitad como inicio
        si frente-libre entonces inicio
            avanza;
            avanza;
            mide-mitad;
            avanza;
        fin sino inicio
            gira-izquierda;
            gira-izquierda;
        fin;
fin;

define-nueva-instruccion rellenadiagonal como inicio
    mientras frente-libre hacer avanza;
    repetir 2 veces gira-izquierda;

    mientras frente-libre hacer inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        gira-izquierda;
        si frente-libre entonces avanza;
        repetir 3 veces gira-izquierda;
        si frente-libre entonces avanza;

    fin;

    si frente-bloqueado entonces inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        situakarel;
    fin;

fin;

define-nueva-instruccion rellenadiagonalinversa como inicio
    mientras frente-libre hacer inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        repetir 3 veces gira-izquierda;
        si frente-libre entonces avanza;
        gira-izquierda;
        si frente-libre entonces avanza;

    fin;

    si frente-bloqueado entonces inicio
        si no junto-a-zumbador entonces deja-zumbador;
        situakarel;
    fin;

fin;

define-nueva-instruccion rellenavertical como inicio
    repetir 3 veces gira-izquierda;
    mide-mitad;
    repetir 3 veces gira-izquierda;
    mientras frente-libre hacer inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        si frente-libre entonces avanza;
    fin;
    si frente-bloqueado entonces inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        situakarel;
    fin;

fin;

define-nueva-instruccion rellenahorizontal como inicio
    mide-mitad;
    gira-izquierda;
    mientras frente-libre hacer inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        si frente-libre entonces avanza;
    fin;

    si frente-bloqueado entonces inicio
        si no-junto-a-zumbador entonces deja-zumbador;
        situakarel;
    fin;

fin;
    inicia-ejecucion

        situakarel;
        rellenadiagonal;
        rellenadiagonalinversa;
        rellenavertical;
        rellenahorizontal;





        apagate;
    termina-ejecucion
finalizar-programa
