iniciar-programa
define-nueva-instruccion gira-derecha como repetir 3 veces gira-izquierda;
define-nueva-instruccion gira-atras como repetir 2 veces gira-izquierda;
define-nueva-instruccion orientarse como inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-derecha;
    mientras frente-libre hacer avanza;
    gira-derecha;
fin;
define-nueva-instruccion diagonal como inicio
    mientras frente-libre hacer inicio
        deja-zumbador;
        si frente-libre entonces avanza;
        gira-derecha;
        si frente-libre entonces avanza;
        gira-izquierda;
    fin;
    deja-zumbador;
    gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda;
    mientras frente-libre hacer inicio
        deja-zumbador;
        si frente-libre entonces avanza;
        gira-izquierda;
        si frente-libre entonces avanza;
        gira-derecha;
    fin;
    deja-zumbador;
    gira-derecha;
    mientras frente-libre hacer avanza;
    gira-derecha;
fin;
define-nueva-instruccion centro como inicio
    mientras frente-libre hacer inicio
        si junto-a-zumbador entonces coge-zumbador;
        si junto-a-zumbador entonces sal-de-instruccion
        sino deja-zumbador;
        si frente-libre entonces avanza;
        gira-derecha;
        si frente-libre entonces avanza;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion cruz como inicio
    mientras frente-libre hacer avanza;
    gira-atras;
    mientras no-junto-a-zumbador hacer inicio
        deja-zumbador;
        avanza;
    fin;
fin;
define-nueva-instruccion completa como inicio
    repetir 2 veces cruz;
    gira-izquierda;
    repetir 2 veces cruz;
fin;
    inicia-ejecucion
        orientarse;
        diagonal;
        centro;
        completa;
        apagate;
    termina-ejecucion
finalizar-programa
