iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion mitad como inicio
        si frente-libre entonces inicio
            repetir 2 veces avanza;
            mitad;
            avanza;
        fin sino inicio
            repetir 2 veces gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion ir11 como inicio
        oeste;
        corre;
        sur;
        corre;
        norte;
    fin;
    define-nueva-instruccion horizontal como inicio
        este;
        mientras no-orientado-al-oeste hacer inicio
            deja-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion vertical como inicio
        norte;
        corre;
        sur;
        mientras no-orientado-al-norte hacer inicio
            si no-junto-a-zumbador entonces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                norte;
            fin;
        fin;
    fin;
    define-nueva-instruccion diagonal1 como inicio
        mientras no-orientado-al-sur hacer inicio
            si no-junto-a-zumbador entonces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                este;
                avanza;
                norte;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;
    define-nueva-instruccion diagonal2 como inicio
        mientras no-orientado-al-norte hacer inicio
            si no-junto-a-zumbador entonces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                este;
                avanza;
                sur;
            fin sino inicio
                norte;
            fin;
        fin;
    fin;
    inicia-ejecucion
        ir11;
        mitad;
        este;
        horizontal;
        mitad;
        vertical;
        ir11;
        diagonal1;
        oeste;
        corre;
        sur;
        diagonal2;
        apagate;
    termina-ejecucion
finalizar-programa
