iniciar-programa
    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion orientar como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
    define-nueva-instruccion orientar-diagonal2 como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
    define-nueva-instruccion orientar-centro como inicio
        mientras frente-libre hacer inicio
            si frente-libre entonces inicio
                avanza;
                si derecha-libre entonces inicio
                    gira-derecha;
                    avanza;
                    gira-izquierda;
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            sal-de-instruccion;
                        fin
                        sino inicio
                            deja-zumbador;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion diagonal como inicio
        si izquierda-bloqueada entonces inicio
            mientras frente-libre hacer inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    si derecha-libre entonces inicio
                        gira-derecha;
                        avanza;
                        gira-izquierda;
                        si frente-bloqueado entonces deja-zumbador;
                    fin;
                fin;
            fin;
        fin
        sino inicio
            si derecha-bloqueada entonces inicio
                mientras frente-libre hacer inicio
                    deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                        si izquierda-libre entonces inicio
                            gira-izquierda;
                            avanza;
                            gira-derecha;
                            si frente-bloqueado entonces deja-zumbador;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion cruz como inicio
        si orientado-al-norte entonces inicio
            gira-izquierda;
            mientras frente-libre hacer avanza;
            media-vuelta;
            mientras frente-libre hacer inicio
                deja-zumbador;
                avanza;
                si frente-bloqueado entonces deja-zumbador;
            fin;
        fin
        sino inicio
            si orientado-al-sur entonces inicio
                mientras frente-libre hacer avanza;
                media-vuelta;
                mientras frente-libre hacer inicio
                    deja-zumbador;
                    avanza;
                    si frente-bloqueado entonces deja-zumbador;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orientar;
        diagonal;
        orientar-diagonal2;
        diagonal;
        orientar;
        orientar-centro;
        cruz;
        orientar;
        orientar-centro;
        media-vuelta;
        cruz;
        orientar;
        orientar-centro;
        apagate;
    termina-ejecucion
finalizar-programa
