iniciar-programa
    define-nueva-instruccion diagonal como inicio
        mientras frente-libre hacer inicio
            si no-junto-a-zumbador entonces deja-zumbador;
            avanza;
            repetir 3 veces gira-izquierda;
            avanza;
            gira-izquierda;
            si no-junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion regreso como inicio
        avanza;
        mientras no-junto-a-zumbador hacer inicio
            avanza;
            si junto-a-zumbador entonces inicio
                sal-de-instruccion;
            fin
            sino inicio
                repetir 3 veces gira-izquierda;
                avanza;
                gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion cruz como inicio
        repetir 4 veces inicio
            mientras frente-libre hacer avanza;
            deja-zumbador;
            repetir 2 veces gira-izquierda;
            avanza;
            mientras no junto-a-zumbador hacer inicio
                deja-zumbador;
                avanza;
            fin;
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion asterisco como inicio
        diagonal;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        diagonal;
        repetir 2 veces gira-izquierda;
        regreso;
        repetir 2 veces gira-izquierda;
        avanza;
        gira-izquierda;
        avanza;
        cruz;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 3 veces gira-izquierda;
        asterisco;
        apagate;
    termina-ejecucion
finalizar-programa
