iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion deja(k) como inicio
       repetir k veces deja-zumbador;
   fin;

    define-nueva-instruccion centro como inicio
        si frente-libre entonces inicio
            avanza;
            avanza;
            centro;
            avanza;
        fin sino inicio
            oeste;
        fin;
    fin;

    define-nueva-instruccion cuadro(n) como inicio
        norte;
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            si no junto-a-zumbador entonces inicio
                deja(n);
                cuadro(sucede(n));
            fin sino inicio
                sur;
                avanza;
                oeste;
                avanza;
                sur;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    norte;
                    mientras frente-libre hacer avanza;
                    si junto-a-zumbador entonces inicio
                        apagate;
                    fin;
                fin;
                deja(n);
                cuadro(sucede(n));
            fin;
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            si no junto-a-zumbador entonces inicio
                deja(n);
                cuadro(sucede(n));
            fin sino inicio
                este;
                mientras frente-libre hacer avanza;
                norte;
                mientras frente-libre hacer avanza;
                sur;
                avanza;
                deja(n);
                cuadro(sucede(n));
            fin;
        fin;
    fin;

    inicia-ejecucion
        norte;
        mientras frente-libre hacer avanza;
        este;
        centro;
        deja-zumbador;
        cuadro(2);
        apagate;
    termina-ejecucion
finalizar-programa
