iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion numero(n) como inicio
        si frente-libre y orientado-al-este entonces inicio
            avanza;
            numero(sucede(n));
        fin;
        si si-es-cero(n) y no-junto-a-zumbador entonces deja-zumbador;
        si no si-es-cero(n) y no-junto-a-zumbador entonces inicio
            si frente-bloqueado entonces gira(2);
            avanza;
            numero(precede(precede(n)));
        fin;
    fin;
    define-nueva-instruccion colocar(n) como inicio
        si junto-a-zumbador entonces inicio
            si frente-bloqueado y derecha-bloqueada entonces inicio
                gira(2);
                avanza;
                gira(2);
                repetir n veces deja-zumbador;
                colocar(sucede(n));
            fin;
            si frente-libre entonces inicio
                avanza;
                gira(3);
            fin sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
            fin;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
            fin;
            si junto-a-zumbador entonces inicio
                gira(2);
                avanza;
                gira(1);
                repetir 2 veces inicio
                    si frente-bloqueado entonces apagate;
                    si frente-libre entonces avanza;
                fin;
            fin;
            repetir n veces deja-zumbador;
            mientras no-orientado-al-norte hacer gira-izquierda;
            colocar(sucede(n));
        fin;
    fin;
    define-nueva-instruccion cuadro(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuadro(sucede(n));
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces deja-zumbador;
            colocar(sucede(n));
        fin;
    fin;
inicia-ejecucion
    mientras no-orientado-al-norte hacer gira-izquierda;
    si derecha-bloqueada y izquierda-bloqueada y frente-bloqueado entonces inicio
        deja-zumbador;
        apagate;
    fin;
    mientras frente-libre hacer avanza;
    gira(3);
    numero(0);
    gira(3);
    cuadro(0);
        apagate;
    termina-ejecucion
finalizar-programa
