iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion medir como inicio
        si frente-libre entonces inicio
            avanza;
            avanza;
            medir;
            avanza;
        fin sino inicio
            este;
        fin;
    fin;

    define-nueva-instruccion marcar(n) como inicio
        repetir n veces deja-zumbador;
        norte;
        si frente-libre y  derecha-libre entonces inicio
            avanza;
            este;
            avanza;
            si junto-a-zumbador entonces inicio
                oeste;
                avanza;
                sur;
                avanza;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    norte;
                    mientras frente-libre hacer avanza;
                fin;
                si junto-a-zumbador entonces apagate;
            fin;
        fin sino inicio
            si frente-bloqueado  y derecha-bloqueada entonces inicio
                sur;
                avanza;
            fin sino inicio
                si frente-bloqueado y derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer avanza;
                    este;
                    avanza;
                fin sino inicio
                    oeste;
                    mientras frente-libre hacer avanza;
                    norte;
                    avanza;
                fin;
            fin;
        fin;
        marcar(sucede(n));
    fin;

    inicia-ejecucion
        norte;
        medir;
        marcar(1);
        apagate;
    termina-ejecucion
finalizar-programa
