iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;

    define-nueva-instruccion mitad como inicio
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces avanza;
            mitad;
            avanza;
        fin sino inicio
            oeste;
        fin;
    fin;

    define-nueva-instruccion buscar_siguiente como inicio
        si izquierda-bloqueada entonces inicio
            si frente-libre entonces inicio
                avanza;
                sur;
                corre;
                este;
            fin sino inicio
                sur;
                avanza;
                este;
            fin;
        fin sino inicio
            norte;
            avanza;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
                corre;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion llenar_cuadro(x) como inicio
        si no-junto-a-zumbador entonces inicio
            repetir x veces deja-zumbador;
            buscar_siguiente;
            llenar_cuadro(sucede(x));
        fin sino inicio
            oeste;
            avanza;
            sur;
            repetir 2 veces si frente-libre entonces avanza;
            este;
            si no-junto-a-zumbador entonces inicio
                llenar_cuadro(x);
            fin sino inicio
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        norte;
        corre;
        este;
        mitad;
        este;
        llenar_cuadro(sucede(0));
        apagate;
    termina-ejecucion
finalizar-programa
