iniciar-programa
    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces gira-izquierda;
    fin;
  (*Despues de formar la ultima columna te ubica en la siguiente columna que hay que recoger*)
 define-nueva-instruccion ubicar como
 inicio
   gira-izquierda;
   gira-izquierda;
   mientras frente-libre hacer avanza;
   gira-derecha;
   avanza;
   mientras no junto-a-zumbador y frente-libre hacer
   inicio
     si frente-libre entonces avanza;
   fin;


 fin;

  define-nueva-instruccion regresa como
    inicio
        repetir 2 veces gira-izquierda;
        mientras junto-a-zumbador hacer avanza;
        avanza;
        gira-izquierda;
    fin;


    (*Forma una sola columa despues de las columnas iniciales*)
    define-nueva-instruccion una-columna como
    inicio
        mientras no orientado-al-norte hacer gira-izquierda;
        mientras algun-zumbador-en-la-mochila hacer
        inicio
           deja-zumbador;
           si frente-libre entonces avanza;
        fin;
    fin;



    inicia-ejecucion
      (*Quita zumbadores*)
        mientras no orientado-al-norte hacer gira-izquierda;
        mientras junto-a-zumbador hacer coge-zumbador;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira-izquierda;
        gira-izquierda;
        avanza;
        gira-izquierda;
        (*Se ubica en la columna 1*)
        mientras no junto-a-zumbador hacer avanza;
        (*Recoge y cambia de posicion la columna 1*)
        mientras junto-a-zumbador hacer
        inicio
           coge-zumbador;

        fin;
        avanza;
        mientras junto-a-zumbador hacer avanza;
        avanza;
        una-columna;
        ubicar;

        (*Recoge y reubica las columas de la 2 en adelante *)

      mientras junto-a-zumbador hacer
      inicio
         mientras junto-a-zumbador hacer
        inicio
           coge-zumbador;

        fin;
        gira-izquierda;
        gira-izquierda;

        mientras no junto-a-zumbador hacer avanza;
        una-columna;
        ubicar;
      fin;

      mientras no orientado-al-este hacer gira-izquierda;
      mientras no junto-a-zumbador hacer avanza;
      gira-izquierda;

      (*Deja el numero mayor de zumbadores*)
      mientras junto-a-zumbador hacer
      inicio
         coge-zumbador;
         si frente-libre entonces avanza;
      fin;
      gira-izquierda;
      gira-izquierda;
      mientras frente-libre hacer avanza;
      gira-derecha;
      avanza;
      avanza;
      mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
      regresa;


       (*deja las  columnas que le anteceden a la mayor*)
    mientras junto-a-zumbador hacer
    inicio
      mientras junto-a-zumbador hacer
      inicio
         coge-zumbador;
         si frente-libre entonces avanza;
      fin;
      gira-izquierda;
      gira-izquierda;
      mientras frente-libre hacer avanza;
      gira-derecha;
      avanza;
      mientras no junto-a-zumbador hacer avanza;
      mientras junto-a-zumbador hacer avanza;
      mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
      regresa;
     fin;
        apagate;
    termina-ejecucion
finalizar-programa
