iniciar-programa
define-nueva-instruccion orientate como inicio
    mientras no-orientado-al-norte hacer gira-izquierda;
fin;
define-nueva-instruccion ubicate como inicio
    mientras junto-a-zumbador hacer coge-zumbador;
    mientras no-orientado-al-este hacer gira-izquierda;
    mientras no-junto-a-zumbador hacer avanza;
fin;
define-nueva-instruccion subelo como inicio
    gira-izquierda;
    avanza;
    deja-zumbador;
    repetir 2 veces gira-izquierda;
    avanza;
    gira-izquierda;
    si junto-a-zumbador entonces avanza
fin;
define-nueva-instruccion vuelve como inicio
    repetir 2 veces gira-izquierda;
    mientras frente-libre hacer avanza;
    repetir 2 veces gira-izquierda;
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
fin;
define-nueva-instruccion regresa como inicio
    mientras frente-libre hacer avanza;
    repetir 2 veces gira-izquierda;
    repetir 2 veces avanza;
    repetir 3 veces gira-izquierda;
    avanza;
    mientras no-junto-a-zumbador hacer avanza;
    coge-zumbador;
    repetir 3 veces gira-izquierda;
    mientras frente-libre hacer avanza;
    gira-izquierda;
fin;
define-nueva-instruccion acomoda(a) como inicio
    mientras frente-libre y no-orientado-al-sur hacer inicio
        si orientado-al-este entonces inicio
            gira-izquierda;
            repetir 2 veces avanza;
            deja-zumbador;
            repetir 2 veces gira-izquierda;
            avanza;
            repetir 3 veces gira-izquierda;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            acomoda(sucede(a));
        fin;
        si frente-libre y no-orientado-al-sur entonces inicio
            mientras frente-libre hacer avanza;
            repetir 3 veces gira-izquierda;
        fin;
        si junto-a-zumbador y frente-libre y no-orientado-al-sur entonces inicio
            mientras junto-a-zumbador hacer avanza;
        fin;
        si no-junto-a-zumbador entonces gira-izquierda;
    fin;
    si orientado-al-oeste entonces inicio
        repetir a veces deja-zumbador;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion recorre como inicio
    mientras frente-libre y junto-a-zumbador hacer inicio
        coge-zumbador;
        subelo;
        si no-junto-a-zumbador entonces inicio
            acomoda(0);
            regresa;
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
        fin;
    fin;
fin;
define-nueva-instruccion ordena(b) como inicio
    mientras orientado-al-norte y junto-a-zumbador hacer inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena(sucede(b));
        fin;
    fin;
    si no-junto-a-zumbador y orientado-al-norte entonces inicio
        repetir 2 veces gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        repetir 2 veces avanza;
        mientras junto-a-zumbador hacer avanza;
    fin;
    deja-zumbador;
fin;
    inicia-ejecucion
        orientate;
        ubicate;
        mientras frente-libre hacer inicio
            recorre;
            vuelve;
        fin;
        si frente-bloqueado entonces inicio
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir 3 veces gira-izquierda;
            avanza;
        fin;
        mientras junto-a-zumbador hacer inicio
            ordena(0);
            coge-zumbador;
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir 3 veces gira-izquierda;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
