iniciar-programa
define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-prototipo-instruccion cuenta(n);
define-nueva-instruccion acomoda(n) como
    inicio
       si orientado-al-oeste entonces cuenta(0);
       si no si-es-cero (n) entonces
           inicio
               si junto-a-zumbador entonces
                   inicio
                      coge-zumbador;
                      acomoda(precede(n));
                      si orientado-al-oeste entonces
                          inicio
                              deja-zumbador;
                          fin;
                   fin sino
                       inicio
                           (*es menor el numero sobre el cual estoy parado*)
                            oeste;
                       fin;
           fin sino
               inicio
                   (*es mayor el numero sobre el cual estoy parado*)
                   este;
                   mientras junto-a-zumbador hacer
                       inicio
                           coge-zumbador;
                           este;
                           avanza;
                           deja-zumbador;
                           oeste;
                           avanza;
                       fin;
                   oeste;
               fin;
    fin;
define-nueva-instruccion cuenta(n) como
    inicio
       si junto-a-zumbador entonces
           inicio
               coge-zumbador;
               cuenta(sucede(n));
           fin sino
               inicio
                   repetir n veces deja-zumbador;
                   avanza;
                   norte;
                   mientras junto-a-zumbador hacer acomoda(n);
               fin;
    fin;
    inicia-ejecucion
        mientras junto-a-zumbador hacer
            inicio
                coge-zumbador;
                este;
                avanza;
                mientras no-junto-a-zumbador hacer avanza;
                mientras junto-a-zumbador y frente-libre hacer avanza;
                oeste;
                si no-junto-a-zumbador entonces
                    inicio
                        avanza;
                    fin;
                cuenta(0);
                avanza;
            fin;
        apagate;
    termina-ejecucion
finalizar-programa
