iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion acomoda como
inicio
  si frente-bloqueado entonces inicio
    este;
    avanza;
    fin;
  mientras no-junto-a-zumbador y frente-libre hacer avanza;
  si frente-bloqueado y no-junto-a-zumbador entonces apagate;
  si junto-a-zumbador entonces
      inicio
          mientras junto-a-zumbador hacer coge-zumbador;
          oeste;
          mientras frente-libre hacer avanza;
          este;
          avanza;
          avanza;
          mientras junto-a-zumbador hacer avanza;
          mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
          avanza;
          acomoda;
      fin;
fin;
define-nueva-instruccion deja como
    inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        norte;
        mientras frente-libre hacer avanza;
        este;
        mientras frente-libre hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
    fin;
define-nueva-instruccion junta como
    inicio
        sur;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
            si frente-libre entonces avanza;
        fin;
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras junto-a-zumbador hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado entonces acomoda;

    fin;
define-nueva-instruccion ubica como
    inicio
        este;
        repetir 2 veces avanza;
        mientras junto-a-zumbador hacer avanza;
        si no-junto-a-zumbador entonces
            inicio
                oeste;
                avanza;
            fin;

    fin;
define-nueva-instruccion estira como
    inicio
    si junto-a-zumbador entonces inicio
        norte;
        mientras junto-a-zumbador hacer coge-zumbador;
        mientras algun-zumbador-en-la-mochila hacer
            inicio
                deja-zumbador;
                si frente-libre entonces avanza;
            fin;
        si frente-bloqueado y junto-a-zumbador entonces coge-zumbador;
            estira;
         fin
       sino
           inicio
               si algun-zumbador-en-la-mochila entonces deja-zumbador;
               sur;
               mientras frente-libre hacer avanza;
               oeste;
               avanza;
               si junto-a-zumbador entonces estira;
           fin;
    fin;





define-nueva-instruccion cuenta como
    inicio
    si no-junto-a-zumbador entonces
      inicio
        avanza;
        ubica;
        cuenta;
      fin
   sino inicio
       norte;
       mientras junto-a-zumbador hacer
           inicio
               si frente-libre entonces avanza
               sino inicio
                   junta;
                   si junto-a-zumbador y frente-libre  entonces cuenta;
               fin;
           fin;
       si no-junto-a-zumbador entonces
           inicio
               oeste;
               mientras no-junto-a-zumbador hacer
               inicio
                   si frente-libre entonces avanza
                   sino inicio
                       sur;
                       avanza;
                       este;
                       mientras no-junto-a-zumbador hacer avanza;
                       junta;
                       si junto-a-zumbador y frente-libre entonces cuenta;
                   fin;
               fin;
               si junto-a-zumbador y frente-libre entonces cuenta
               sino inicio
                   acomoda;
                   apagate;
               fin;

           fin;
   fin;

    fin;


   inicia-ejecucion
       deja;
        ubica;
        estira;
        cuenta;
        apagate;
    termina-ejecucion
finalizar-programa
    
