iniciar-programa
define-nueva-instruccion gira-derecha como
inicio
    repetir 3 veces gira-izquierda;
fin;
define-nueva-instruccion media-vuelta como
inicio
    gira-izquierda;
    gira-izquierda;
fin;
define-nueva-instruccion filas como
inicio
    mientras junto-a-zumbador hacer
    inicio
        gira-izquierda;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
        fin;
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
            avanza;
        fin;
        media-vuelta;
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
        gira-izquierda;
        si frente-libre entonces
        inicio
            avanza;
        fin
        sino inicio
            media-vuelta;
            mientras frente-libre hacer
            inicio
                avanza;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion ordenar como
inicio
    mientras no-orientado-al-oeste hacer
    inicio
        gira-izquierda;
    fin;
    mientras frente-libre hacer
    inicio
        avanza;
    fin;
    media-vuelta;
    avanza;
    si no-junto-a-zumbador entonces apagate;
    si junto-a-zumbador entonces
    inicio
    gira-izquierda;
    mientras junto-a-zumbador hacer
    inicio
        avanza;
    fin;
    media-vuelta;
    avanza;
    mientras junto-a-zumbador hacer
    inicio
        coge-zumbador;
    fin;
    si frente-libre entonces avanza;
    mientras junto-a-zumbador y frente-libre hacer
    inicio
        avanza;
    fin;
    gira-izquierda;
    avanza;
    mientras junto-a-zumbador hacer
    inicio
        avanza;
    fin;
    mientras algun-zumbador-en-la-mochila hacer
    inicio
        deja-zumbador;
    fin;
    fin;
    ordenar;
fin;

define-nueva-instruccion colocar como
inicio
    mientras no-orientado-al-oeste hacer
    inicio
        gira-izquierda;
    fin;
      mientras frente-libre hacer
      inicio
        avanza;
      fin;
      media-vuelta;
      avanza;
      si no-junto-a-zumbador entonces
      inicio
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
        fin;
      fin
      sino inicio
        gira-izquierda;
        mientras junto-a-zumbador hacer
        inicio
            avanza;
        fin;
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
        fin;
        media-vuelta;
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
        gira-izquierda;
      fin;
    fin;

define-nueva-instruccion busca-mayor como
inicio
    mientras frente-libre hacer
    inicio
        si junto-a-zumbador entonces
        inicio
            gira-izquierda;
            mientras junto-a-zumbador hacer
            inicio
               avanza;
            fin;
            media-vuelta;
            avanza;
            gira-izquierda;
         fin;
         avanza;
    fin;
      media-vuelta;
      mientras (frente-libre) y (no-junto-a-zumbador) hacer
      inicio
         avanza;
      fin;
    si junto-a-zumbador entonces
      inicio
         gira-izquierda;
         si frente-libre entonces
         inicio
            mientras junto-a-zumbador hacer
            inicio
                coge-zumbador;
                si frente-libre entonces avanza;
            fin;
         fin
         sino inicio
            gira-derecha;
            avanza;
            mientras no-junto-a-zumbador y frente-libre hacer
            inicio
                avanza;
            fin;
                media-vuelta;
                avanza;
                mientras no-junto-a-zumbador hacer
                inicio
                    avanza;
                fin;
                gira-izquierda;
                avanza;
                si no-junto-a-zumbador entonces
                inicio
                    media-vuelta;
                    avanza;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    colocar;
                fin
                sino inicio
                    media-vuelta;
                    avanza;
                    ordenar;
                fin;
         fin;
    fin;
fin;

define-nueva-instruccion hacer-torre como
inicio
        avanza;
        busca-mayor;
        colocar;
        hacer-torre;
fin;
    inicia-ejecucion
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
        fin;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
        fin;
        media-vuelta;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
        avanza;
        avanza;
        avanza;
        si junto-a-zumbador entonces
        inicio
            media-vuelta;
            avanza;
            media-vuelta;
            filas;
        fin
        sino inicio
            apagate;
        fin;
        si orientado-al-oeste entonces
        inicio
            media-vuelta;
            avanza;
            avanza;
        fin
        sino inicio
            si orientado-al-este entonces
            inicio
                media-vuelta;
                mientras frente-libre hacer
                inicio
                    avanza;
                fin;
                media-vuelta;
                avanza;
                avanza;
            fin;
        fin;
        busca-mayor;
        colocar;
        hacer-torre;
        apagate;
    termina-ejecucion
finalizar-programa