iniciar-programa
define-nueva-instruccion acomodar(x) como inicio
    si orientado-al-oeste entonces inicio
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
    si no-junto-a-zumbador y frente-libre entonces inicio
        avanza;
        acomodar(sucede(x));
    fin;
    si junto-a-zumbador entonces inicio
        repetir x veces coge-zumbador;
        coge-zumbador;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        repetir 2 veces avanza;
        mientras junto-a-zumbador hacer avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        acomodar(0);
   fin;
fin;

define-nueva-instruccion contar(x) como inicio
    si junto-a-zumbador y orientado-al-oeste entonces inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        coge-zumbador;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces contar(sucede(x))
        sino contar(x);

    fin
    sino inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-norte hacer gira-izquierda;
        si frente-libre entonces avanza;
        mientras no-orientado-al-este hacer gira-izquierda;
        repetir x veces avanza;
        repetir x veces deja-zumbador;
        deja-zumbador;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        avanza;
        mientras no-orientado-al-oeste hacer gira-izquierda;
        si junto-a-zumbador entonces contar(0)
        sino acomodar(0);
     fin;
 fin;

    inicia-ejecucion
    mientras no-orientado-al-oeste hacer gira-izquierda;
    contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
