iniciar-programa
   define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion orientar como
    inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
    fin;

    define-nueva-instruccion quitar como
    inicio
        norte;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir 2 veces avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        orientar;
        este;
    fin;

    define-nueva-instruccion contar-zum como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            contar-zum;
            si frente-libre entonces avanza;
        fin sino
        inicio
            orientar;
            norte;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion ordenar-arriba como
    inicio
        mientras frente-libre hacer
        inicio
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador entonces
            inicio
                contar-zum;
                si frente-libre entonces
                inicio
                    oeste;
                    avanza;
                fin;
                deja-zumbador;
                orientar;
                este;
            fin sino orientar;
        fin;
    fin;

    define-nueva-instruccion contar-pasos como
    inicio
        si frente-libre y no-junto-a-zumbador entonces
        inicio
            avanza;
            contar-pasos;
        fin sino
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            orientar;
            este;
            repetir 2 veces avanza;
            mientras frente-libre y junto-a-zumbador hacer avanza;
        fin sino orientar;
        si algun-zumbador-en-la-mochila entonces deja-zumbador;
    fin;

    define-nueva-instruccion ordenar-abajo como
    inicio
        norte;
        mientras frente-libre hacer
        inicio
            avanza;
            este;
            contar-pasos;
            orientar;
            si algun-zumbador-en-la-mochila entonces norte;
        fin;
    fin;

    inicia-ejecucion
        si junto-a-zumbador entonces
        inicio
            quitar;
            ordenar-arriba;
            ordenar-abajo;
         fin;
        apagate;
    termina-ejecucion
finalizar-programa
