iniciar-programa
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como
    mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como
    mientras no orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion comparar(a)como inicio
    si junto-a-zumbador y no si-es-cero(a) entonces inicio
        coge-zumbador;
        comparar(precede(a));
        si orientado-al-norte o orientado-al-oeste  entonces deja-zumbador;
    fin sino inicio
        si junto-a-zumbador y si-es-cero(a) entonces inicio
            este;
        fin;
        si no junto-a-zumbador y no si-es-cero(a) entonces norte;
        si no junto-a-zumbador y si-es-cero(a) entonces oeste;
    fin;
fin;
define-nueva-instruccion borbuja(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        borbuja(sucede(a));
    fin sino inicio
        oeste;
        avanza;
        comparar(a);
        si orientado-al-norte entonces inicio
            este;
            avanza;
            repetir a veces deja-zumbador;
        fin sino inicio
            si orientado-al-este entonces inicio
                norte;
                avanza;
                repetir a veces deja-zumbador;
                sur;
                avanza;
                este;
                avanza;
                repetir a veces deja-zumbador;
                oeste;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                este;
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                oeste;
                avanza;
                norte;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                sur;
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                este;
                avanza;
            fin sino inicio
                si orientado-al-oeste entonces inicio
                    este;
                    avanza;
                    repetir a veces deja-zumbador;
                fin;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion parejas(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        parejas(sucede(a));
        mientras junto-a-zumbador hacer inicio
            avanza;
            si junto-a-zumbador entonces borbuja(0);
        fin;
        si no junto-a-zumbador entonces inicio
            oeste;
            avanza;
            mientras  junto-a-zumbador hacer avanza;
            este;
            avanza;
        fin;
    fin sino inicio
        repetir a veces deja-zumbador;
        repetir 2 veces avanza;
    fin;
fin;

    inicia-ejecucion
        este;
        parejas(0);
        apagate;
    termina-ejecucion
finalizar-programa
 