iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;
    define-nueva-instruccion quita como inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        norte;
        avanza;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
        avanza;
        este;
    fin;
    define-nueva-instruccion pon como inicio
        si no-junto-a-zumbador y frente-libre entonces inicio
            avanza;
            pon;
            deja-zumbador;
        fin sino inicio
            si frente-bloqueado y no-junto-a-zumbador entonces apagate;
            coge-zumbador;
            ir11;
            avanza;
            avanza;
            mientras junto-a-zumbador hacer avanza;
        fin;
    fin;
    define-nueva-instruccion acomoda como inicio
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        este;
        mientras frente-libre hacer inicio
            pon;
            deja-zumbador;
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion busca como inicio
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            acomoda;
            apagate;
        fin;
    fin;
    define-nueva-instruccion toma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            toma(sucede(n));
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            repetir precede(n) veces avanza;
            deja-zumbador;
            ir11;
        fin;
    fin;
    inicia-ejecucion
        quita;
        mientras frente-libre hacer inicio
            busca;
            toma(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
