iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            compara(precede(n));
            deja-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                norte;
            fin sino inicio
                sur;
            fin;
        fin;
    fin;

    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    compara(n);
                    si orientado-al-norte entonces inicio
                        oeste;
                        avanza;
                        repetir n veces deja-zumbador;
                        este;
                        si frente-libre entonces avanza;
                    fin;
                    si orientado-al-sur entonces inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        repetir n veces deja-zumbador;
                        oeste;
                        si frente-libre entonces avanza;
                        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                        este;
                        si frente-libre entonces avanza;
                    fin;
                fin sino inicio
                    oeste;
                    avanza;
                    mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                fin;
            fin sino inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                oeste;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin sino inicio
            norte;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            sur;
            avanza;
            repetir n veces inicio
                oeste;
                mientras frente-libre hacer avanza;
                este;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                mientras junto-a-zumbador y orientado-al-este hacer inicio
                    ordena(0);
                fin;
            fin;
        fin;
    fin;


    inicia-ejecucion
        este;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
