iniciar-programa
    define-nueva-instruccion Este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion Oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion regresar como inicio
        Oeste;
        avanza;
        mientras junto-a-zumbador hacer avanza;
        Este;
        avanza;
    fin;

    define-nueva-instruccion comparar(m) como inicio
        si no si-es-cero(m) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                comparar(precede(m));
                deja-zumbador;
            fin
            sino inicio
                repetir m veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion recogerYcomparar(m) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recogerYcomparar(sucede(m));
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        fin
        sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
            comparar(m);
            fin;
            Oeste;
            avanza;
        fin;
    fin;

    define-nueva-instruccion ordenar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordenar(sucede(n));
        fin
        sino inicio
            repetir n veces deja-zumbador;
            repetir 2 veces avanza;
            repetir precede(n) veces inicio
                regresar;
                    repetir precede (n) veces inicio
                        recogerYcomparar(0);
                        Este;
                        avanza;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        Este;
        si junto-a-zumbador entonces inicio
            ordenar(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
