iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion llegar como inicio
         este;
         repetir 3 veces avanza;
    fin;
    define-nueva-instruccion marcaPos como inicio
        norte;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
    fin;
    define-nueva-instruccion menor(a) como inicio
        si junto-a-zumbador y no si-es-cero(a) entonces inicio
            coge-zumbador;
            menor(precede(a));
            deja-zumbador;
        fin  sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion compara2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara2(sucede(n));
        fin sino inicio
            oeste;
            avanza;
            menor(n);
            este;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            oeste;
            avanza;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        norte;
        avanza;
        este;
        mientras no-junto-a-zumbador hacer avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        sur;
        avanza;
        este;
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
        fin;
    fin;
    define-nueva-instruccion comparar como inicio
        si junto-a-zumbador y no-orientado-al-oeste entonces inicio
            marcaPos;
            oeste;
            mientras junto-a-zumbador hacer compara2(0);
            regresa;
            comparar;
        fin;
    fin;
    inicia-ejecucion
        mientras junto-a-zumbador hacer coge-zumbador;
        llegar;
        comparar;
        apagate;
    termina-ejecucion
finalizar-programa
