iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion cambiar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cambiar(sucede(n));
        fin sino inicio
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            si no-junto-a-zumbador entonces inicio
                repetir n veces deja-zumbador;
                gira(2);
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                gira(2);
                avanza;
            fin sino inicio
                gira(2);
                avanza;
                repetir n veces deja-zumbador;
                gira(2);
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(elementos) como inicio
        si junto-a-zumbador y orientado-al-norte entonces inicio
            coge-zumbador;
            cuenta(sucede(elementos));
        fin sino inicio
            mientras no-orientado-al-este hacer gira-izquierda;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir 2 veces avanza;
            si si-es-cero(precede(elementos)) entonces apagate;
            repetir precede(elementos) veces inicio
                repetir precede(elementos) veces inicio
                    cambiar(0);
                fin;
                gira(2);
                mientras frente-libre hacer avanza;
                cuenta(precede(elementos));
            fin;
        fin;
    fin;

    inicia-ejecucion
        si junto-a-zumbador entonces inicio
            mientras no-orientado-al-norte hacer gira-izquierda;
            cuenta(0);
        fin sino inicio
            apagate;
        fin;
    termina-ejecucion
finalizar-programa
