iniciar-programa
define-nueva-instruccion gira (r) como inicio
repetir r veces gira-izquierda;
fin;



define-nueva-instruccion cambia (p) como inicio
 si junto-a-zumbador entonces inicio
  coge-zumbador;
   cambia (p);
    deja-zumbador;
    fin
    sino inicio
    repetir p veces deja-zumbador;
    gira (2);
   avanza;
 fin;
fin;



define-nueva-instruccion intercambia (p) como inicio
 si junto-a-zumbador entonces inicio
  coge-zumbador;
   intercambia (sucede(p));
     fin
     sino inicio
     avanza;
     cambia (p);

 fin;
fin;



define-nueva-instruccion sort2 (m) como inicio
 si junto-a-zumbador y no si-es-cero (m) entonces inicio
  coge-zumbador;
   sort2 (precede(m));
    deja-zumbador;
    fin
   sino inicio
  si no si-es-cero (m) y no junto-a-zumbador entonces gira (2);
 fin;
fin;



define-nueva-instruccion sort (m) como inicio
 si junto-a-zumbador entonces inicio
  coge-zumbador;
   sort (sucede(m));
    fin
    sino inicio
    repetir m veces deja-zumbador;
   avanza;
  sort2 (m);
 fin;
fin;



define-nueva-instruccion ordena (k) como inicio
 si no si-es-cero (k) entonces inicio
  repetir k veces inicio
   sort (0);
    si orientado-al-oeste entonces intercambia (0);
     fin;

     gira (2);
     mientras frente-libre hacer avanza;
    gira (2);
   ordena (precede(k));
  fin;
fin;



define-nueva-instruccion bubble (k) como inicio
 si frente-libre entonces inicio
  avanza;
   bubble (sucede(k));
   fin
   sino inicio
   gira (2);
  ordena (k);
 fin;
fin;


    inicia-ejecucion

    mientras no-orientado-al-este hacer gira-izquierda;
    mientras junto-a-zumbador hacer coge-zumbador;
    repetir 2 veces avanza;
    mientras junto-a-zumbador y frente-libre hacer avanza;
    gira (2);
    si no-junto-a-zumbador entonces avanza;
    bubble (0);

        apagate;
    termina-ejecucion
finalizar-programa
