iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion deja(x) como repetir x veces deja-zumbador;

    define-nueva-instruccion coge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge(sucede(n));
        fin
        sino inicio
            repetir n veces inicio
                si frente-libre entonces avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    gira(2);
                    avanza;
                    gira(2);
                    deja-zumbador;
                fin
                sino inicio
                   deja(n);
                   sal-de-instruccion;
                fin;
            fin;
            avanza;
            deja(n);
        fin;
    fin;

    define-nueva-instruccion ordena como inicio
        repetir 2 veces avanza;
        mientras junto-a-zumbador y frente-libre hacer inicio
            coge(0);
            si frente-libre entonces avanza;
            si junto-a-zumbador entonces inicio
                gira(2);
                avanza;
                gira(2);
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(n));
        fin
        sino inicio
            deja-zumbador;
            si ningun-zumbador-en-la-mochila entonces apagate;
            repetir n veces inicio
                ordena;
                gira(2);
                mientras frente-libre hacer avanza;
                gira(2);
            fin;
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-este hacer gira(1);
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
