iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion come como
        inicio
           mientras orientado-al-norte hacer
               inicio
                  mientras no-junto-a-zumbador y frente-libre hacer avanza;
                  si frente-bloqueado y no-junto-a-zumbador entonces apagate;
                  si junto-a-zumbador entonces
                      inicio
                         este;
                         mientras junto-a-zumbador hacer avanza;
                         oeste;
                         si frente-libre entonces avanza;
                         mientras junto-a-zumbador hacer coge-zumbador;
                         mientras frente-libre hacer avanza;
                         sur;
                         mientras frente-libre hacer avanza;
                         este;
                         repetir 2 veces avanza;
                         mientras junto-a-zumbador hacer avanza;
                         mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                         oeste;
                         mientras frente-libre hacer avanza;
                         norte;
                      fin;
               fin;
        fin;

    define-nueva-instruccion cuenta(G) como
        inicio
           si orientado-al-norte entonces come;
           si junto-a-zumbador entonces
               inicio
                  coge-zumbador;
                  cuenta(sucede(G));
               fin sino
                   inicio
                      oeste;
                      mientras frente-libre hacer avanza;
                      norte;
                      repetir g veces
                          inicio
                             si frente-libre entonces avanza;
                          fin;
                      si junto-a-zumbador entonces
                          inicio
                             este;
                             avanza;
                             mientras junto-a-zumbador hacer avanza;
                         fin;
                      mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                      sur;
                      mientras frente-libre hacer avanza;
                      oeste;
                   fin;
        fin;

    define-nueva-instruccion llegar como
        inicio
           mientras orientado-al-oeste hacer
               inicio
                  este;
                  si frente-libre entonces avanza;
                  mientras no-junto-a-zumbador y frente-libre hacer avanza;
                  si frente-bloqueado y no-junto-a-zumbador entonces
                      inicio
                         oeste;
                         mientras frente-libre hacer avanza;
                         norte;
                         cuenta(0);
                      fin;
                  cuenta(0);
               fin;
        fin;

    define-nueva-instruccion quitar como
        inicio
           norte;
           mientras junto-a-zumbador hacer coge-zumbador;
           este;
           mientras frente-libre hacer avanza;
           norte;
           avanza;
           mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
           sur;
           avanza;
           oeste;
           mientras frente-libre hacer avanza;
           llegar;
        fin;
    inicia-ejecucion
        quitar;
        apagate;
    termina-ejecucion
finalizar-programa
