iniciar-programa
    define-nueva-instruccion busk(k) como
    inicio
        si si-es-cero(k) entonces apagate;
        si no-junto-a-zumbador entonces
        inicio
            repetir k veces deja-zumbador;
            repetir 4 veces
            inicio
                si frente-libre entonces
                inicio
                    avanza;
                    busk(precede(k));
                    repetir 2 veces gira-izquierda;
                    avanza;
                    repetir 2 veces gira-izquierda;
                fin;
                gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta(h) como
    inicio
        si frente-libre entonces
        inicio
            avanza;
            cuenta(sucede(h));
        fin
        sino
        inicio
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            gira-izquierda;
            si frente-libre entonces
            inicio
                avanza;
                gira-izquierda;
                cuenta(sucede(h));
            fin
            sino
            inicio
                repetir 2 veces gira-izquierda;
                mientras frente-libre hacer avanza;
                repetir 3 veces gira-izquierda;
                mientras frente-libre hacer avanza;
                repetir 2 veces gira-izquierda;
                busk(h);
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        cuenta(1);
        apagate;
    termina-ejecucion
finalizar-programa
