iniciar-programa
define-nueva-instruccion g(n) como repetir n veces gira-izquierda;
define-nueva-instruccion muevete como
inicio
        si junto-a-zumbador entonces apagate;
        si frente-libre entonces
        inicio
                avanza;
                si izquierda-libre entonces
                inicio
                     gira-izquierda;
                     avanza;
                      si izquierda-libre entonces
                      inicio
                     gira-izquierda;
                     avanza;
                     fin;
                fin;
        fin
        sino
        inicio
              mientras frente-bloqueado hacer g(3);
              avanza;
              si izquierda-libre entonces
              inicio
                  gira-izquierda;
                  avanza;
                  si izquierda-libre entonces
                   inicio
                     gira-izquierda;
                     avanza;
                   fin;
              fin;
        fin;
fin;
define-nueva-instruccion regresa como
inicio
       si junto-a-zumbador entonces apagate;
       si frente-libre entonces
        inicio
                avanza;
                si derecha-libre entonces
                inicio
                     g(3);
                     avanza;
                     si derecha-libre entonces
                     inicio
                         g(3);
                         avanza;
                    fin;
                fin;
        fin
        sino
        inicio
              mientras frente-bloqueado hacer gira-izquierda;
              avanza;
              si derecha-libre entonces
              inicio
                  g(3);
                  avanza;
                   si derecha-libre entonces
                    inicio
                     g(3);
                     avanza;
                    fin;
              fin;
        fin;
fin;
define-nueva-instruccion binario(b) como
inicio
      si junto-a-zumbador entonces apagate;
      si no si-es-cero(b) entonces
      inicio
           binario(precede(b));
           binario(precede(b));
      fin;
      muevete;
fin;
define-nueva-instruccion binaria(a) como
inicio
      si no si-es-cero(a) entonces
      inicio
           binaria(precede(a));
           binaria(precede(a));
      fin;
      regresa;
fin;
define-nueva-instruccion vamos(v) como
inicio
       si junto-a-zumbador entonces apagate;
       si si-es-cero(v) entonces
       inicio
              mientras izquierda-libre hacer gira-izquierda;
              muevete;
              g(2);
              regresa;
              mientras frente-libre hacer gira-izquierda;
              binaria(sucede(v));
              g(2);
              binario(sucede(v));
       fin
       sino
       inicio
            mientras izquierda-libre hacer gira-izquierda;
            binario(v);
            g(2);
            binaria(v);
            mientras frente-libre hacer gira-izquierda;
            binaria(sucede(v));
            g(2);
            binario(sucede(v));
       fin;
       vamos(sucede(sucede(v)));
fin;
    inicia-ejecucion
        vamos(0);
        apagate;
    termina-ejecucion
finalizar-programa
