iniciar-programa
    define-nueva-instruccion avanzandoizquierda como
    inicio
        si izquierda-libre entonces gira-izquierda;
        si frente-bloqueado entonces repetir 3 veces gira-izquierda;
        si frente-libre entonces
        inicio
            si junto-a-zumbador entonces apagate;
            avanza;
            si junto-a-zumbador entonces apagate;
        fin;
    fin;
    define-nueva-instruccion avanzaderecha como inicio
        si derecha-libre entonces repetir 3 veces gira-izquierda;
        mientras frente-bloqueado hacer gira-izquierda;
        si frente-libre entonces
        inicio
            si junto-a-zumbador entonces apagate;
            avanza;
            si junto-a-zumbador entonces apagate;
        fin;
    fin;
    define-nueva-instruccion avanzadosizquierda(n) como
    inicio
        si no si-es-cero(n) entonces
        inicio
            avanzadosizquierda(precede(n));
            avanzadosizquierda(precede(n));
        fin sino
        inicio
            avanzandoizquierda;
        fin;
    fin;
    define-nueva-instruccion avanzadosderecha(n) como
    inicio
        si no si-es-cero(n) entonces
        inicio
            avanzadosderecha(precede(n));
            avanzadosderecha(precede(n));
        fin sino
        inicio
            avanzaderecha;
        fin;
    fin;
    define-nueva-instruccion vida(n) como
    inicio
        avanzadosizquierda(n);
        repetir 2 veces gira-izquierda;
        avanzadosderecha(n);
        avanzadosderecha(sucede(n));
        repetir 2 veces gira-izquierda;
        avanzadosizquierda(sucede(n));
        vida(sucede(sucede(n)));
    fin;
    inicia-ejecucion
        si junto-a-zumbador entonces apagate;
        mientras izquierda-libre hacer gira-izquierda;
        vida(0);
        apagate;
    termina-ejecucion
finalizar-programa

