iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
define-nueva-instruccion vuelta como repetir 2 veces gira-izquierda;
define-nueva-instruccion irsig como inicio
    sur;
    si frente-libre entonces inicio
        avanza;
        este;
        avanzar;
        oeste;
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
    fin
fin;
define-nueva-instruccion ir como inicio
    norte;
    avanzar;
    este;
    avanzar;
    oeste;
    mientras no-junto-a-zumbador hacer inicio
        si frente-libre entonces inicio
            mientras frente-libre y no-junto-a-zumbador hacer avanza;
        fin sino inicio
            sur;
            si frente-libre entonces inicio
                irsig;
            fin sino inicio
                si no-junto-a-zumbador entonces apagate;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion pinta(n) como inicio
    repetir n veces inicio
        repetir precede(n) veces inicio
            deja-zumbador;
            avanza;
        fin;
        si no-junto-a-zumbador y (no si-es-cero(n)) entonces inicio
            deja-zumbador;
            vuelta;
            repetir precede(n) veces avanza;
            vuelta;
        fin;
        norte;
        si frente-libre entonces inicio
            avanza;
            este;
        fin;
    fin;
    sur;
    si junto-a-zumbador entonces inicio
        repetir precede(n) veces avanza;
    fin sino inicio
        repetir n veces avanza;
    fin;
    este;
fin;
define-nueva-instruccion busca(n) como inicio
    si junto-a-zumbador entonces inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        busca(n);
        este;
        pinta(n);
    fin sino inicio
        si frente-bloqueado y izquierda-libre  entonces inicio
            irsig;
            busca(n);
            oeste;
            avanzar;
            norte;
            repetir n veces si frente-libre entonces avanza;
            este;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                busca(n);
                este;
                repetir n veces si frente-libre entonces avanza;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion toma(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        toma(sucede(n));
    fin sino inicio
        deja-zumbador;
        busca(n);
    fin;
fin;

    inicia-ejecucion
    ir;
    toma(0);
        apagate;
    termina-ejecucion
finalizar-programa
