iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
    define-nueva-instruccion f(x) como inicio
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            f(x);
            norte;
            repetir x veces inicio
                este;
                deja-zumbador;
                repetir precede(x) veces inicio
                    avanza;
                    deja-zumbador;
                fin;
                oeste;
                repetir precede(x) veces avanza;
                norte;
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
            sur;
            mientras no junto-a-zumbador hacer avanza;
            repetir precede (x) veces avanza;
            norte;
            si no junto-a-zumbador entonces inicio
                avanza;
            fin;
         fin sino inicio
            si frente-libre entonces inicio
                avanza;
                f(x);
                norte;
                repetir x veces inicio
                    si frente-libre entonces avanza;

                fin;
            fin sino inicio
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    avanzar;
                    sur;
                    f(x);
                    este;
                    si frente-libre entonces inicio
                        repetir x veces avanza;
                        sur;
                        avanzar;
                        norte;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion parametro(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            parametro(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            norte;
            mientras frente-libre hacer avanza;
            sur;
            f(n);
        fin;
    fin;
    define-nueva-instruccion buscar como inicio
        este;
        avanzar;
        sur;
        avanzar;
        norte;
        mientras no junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                si orientado-al-norte entonces inicio
                    gira-izquierda;
                    avanza;
                    sur;
                fin sino inicio
                    oeste;
                    avanza;
                    norte;
                fin;
            fin;
       fin;
       parametro(0);
    fin;
    inicia-ejecucion
        buscar;
        apagate;
    termina-ejecucion
finalizar-programa
