iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion cuadro(n) como inicio
        norte;
        repetir n veces inicio
            repetir n veces inicio
                deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            si no junto-a-zumbador entonces inicio
                sur;
                avanza;
            fin sino inicio
                sur;
            fin;
            repetir precede(n) veces avanza;
            este;
            si frente-libre entonces avanza;
            norte;
        fin;
        si no junto-a-zumbador entonces inicio
            oeste;
            avanza;
        fin sino inicio
            oeste;
        fin;
        repetir precede(n) veces avanza;
        este;
    fin;



    define-nueva-instruccion ordena(n) como inicio
        si junto-a-zumbador entonces inicio
            repetir n veces coge-zumbador;
            ordena(n);
            cuadro(n);
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                ordena(n);
                repetir n veces inicio
                    si frente-libre entonces avanza;
                fin;
            fin sino inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    este;
                    mientras frente-libre hacer avanza;
                    oeste;
                    ordena(n);
                    norte;
                    repetir n veces inicio
                        si frente-libre entonces avanza;
                    fin;
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                fin sino inicio
                    este;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            ordena(n);
        fin;
    fin;

    define-nueva-instruccion buscaBeep como inicio
        mientras no junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    este;
                    mientras frente-libre hacer avanza;
                    oeste;
                fin sino inicio
                    apagate;
                fin;
            fin;
        fin;
        recoge(0);
    fin;

    inicia-ejecucion
        este;
        mientras frente-libre hacer avanza;
        norte;
        mientras frente-libre hacer avanza;
        oeste;
        buscaBeep;
        apagate;
    termina-ejecucion
finalizar-programa
