iniciar-programa
define-prototipo-instruccion  mundo(n);
define-nueva-instruccion ubicate como
inicio
    mientras no-orientado-al-norte hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    repetir 3 veces gira-izquierda;
    mientras frente-libre hacer avanza;
    repetir 2 veces gira-izquierda;
fin;
define-nueva-instruccion comprueba como
inicio
    mientras no-junto-a-zumbador hacer avanza;
    coge-zumbador;
    si no-junto-a-zumbador entonces
    inicio
       deja-zumbador;
       avanza;
       comprueba;
    fin;
fin;
define-nueva-instruccion regresa(n) como
inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    si frente-libre  entonces
    inicio
        repetir n veces avanza;
        regresa(n);
        avanza;
    fin sino repetir 2 veces gira-izquierda;
fin;
define-nueva-instruccion ancho(n) como
inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
    si frente-libre  entonces
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            repetir 2 veces gira-izquierda;
            repetir n veces avanza;
            sal-de-instruccion;
        fin;
        ancho(n);
        si no-orientado-al-norte entonces repetir 2 veces gira-izquierda;
        repetir n veces avanza;
    fin sino repetir 2 veces gira-izquierda;
fin;
define-nueva-instruccion largo(n) como
inicio
    mientras no-orientado-al-oeste hacer gira-izquierda;
    si frente-libre  entonces
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            repetir 2 veces gira-izquierda;
            repetir n veces avanza;
            sal-de-instruccion;
        fin;
        largo(n);
        si no-orientado-al-este entonces repetir 2 veces gira-izquierda;
        repetir n veces avanza;
    fin sino repetir 2 veces gira-izquierda;
fin;
define-nueva-instruccion cuenta(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        cuenta(sucede(n));
    fin sino
    inicio
        repetir n veces deja-zumbador;
        mundo(n);
    fin;
 fin;
define-nueva-instruccion dibuja(n) como
inicio
    largo(n);
    ancho(n);
    repetir n veces
    inicio
        repetir n veces
        inicio
            deja-zumbador;
            si frente-libre entonces avanza;
        fin;
        repetir 2 veces gira-izquierda;
        repetir n veces si frente-libre entonces avanza;
        gira-izquierda;
        si frente-libre entonces avanza;
        gira-izquierda;
    fin;
    regresa(n);
    gira-izquierda;
    comprueba;
    mientras junto-a-zumbador hacer coge-zumbador;
fin;
define-nueva-instruccion mundo(n) como
inicio
    si si-es-cero(n) y junto-a-zumbador entonces cuenta(n);
    si si-es-cero(precede(n)) entonces apagate;
    si junto-a-zumbador entonces dibuja(n);
    si frente-libre entonces
    inicio
        avanza;
        mundo(n);
    fin sino
    si izquierda-libre entonces inicio
        si si-es-cero(n) y junto-a-zumbador entonces cuenta(n);
        si junto-a-zumbador entonces dibuja(n);
        gira-izquierda;
        avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        mundo(n);
    fin;
 fin;
    inicia-ejecucion
        ubicate;
        mundo(0);
        apagate;
    termina-ejecucion
finalizar-programa
