iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion NxN(n)como inicio
        repetir n veces inicio
            repetir n veces inicio
                este;
                deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            oeste;
            si no-junto-a-zumbador entonces inicio
                oeste;
                repetir n veces avanza
            fin sino inicio
                oeste;
                repetir precede(n) veces avanza;
            fin;
            norte;
            si frente-libre entonces avanza;
        fin;
        sur;
        si no-junto-a-zumbador entonces inicio
            repetir n veces avanza;
        fin sino inicio
            repetir precede(n) veces avanza;
        fin;
        este;
        mientras junto-a-zumbador y frente-libre hacer avanza;
    fin;
    define-prototipo-instruccion recoge(x);
    define-nueva-instruccion camina(x) como inicio
        si frente-libre entonces inicio
            avanza;
            recoge(x);
            este;
            repetir x veces si frente-libre entonces avanza;

        fin sino inicio
            este;
            mientras no junto-a-zumbador hacer avanza;
            coge-zumbador;
            sur;
            si frente-libre entonces inicio
                avanza;
                deja-zumbador;
                oeste;
                avanza;
                recoge(x);
                norte;
                repetir x veces si  frente-libre entonces  avanza;
                oeste;
                corre;
                este;
                repetir x veces si frente-libre entonces avanza;
            fin sino inicio
                oeste;
                corre;
                norte;
                recoge(x);
                este;
                repetir x veces si frente-libre entonces avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion recoge(x) como inicio
        si no-orientado-al-norte entonces inicio
            si junto-a-zumbador entonces inicio
                 mientras junto-a-zumbador hacer coge-zumbador;
                 si frente-libre entonces inicio
                    avanza;
                    recoge(x);
                    NxN(x);
                 fin sino inicio
                    este;
                    mientras no junto-a-zumbador hacer avanza;
                    coge-zumbador;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        deja-zumbador;
                        oeste;
                        avanza;
                        recoge(x);
                        norte;
                        repetir x veces si frente-libre entonces  avanza;
                        oeste;
                        corre;
                        NxN(x);
                    fin sino inicio
                        oeste;
                        corre;
                        norte;
                        recoge(x);
                        NxN(x);
                    fin;
                fin;
            fin sino inicio
                camina(x);
            fin;
        fin;
    fin;
    define-nueva-instruccion agarra(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            agarra(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            este;
            avanza;
            mientras no-junto-a-zumbador hacer avanza;
            oeste;
            avanza;
            recoge(x);
        fin;
    fin;
    define-nueva-instruccion ir-final(x) como inicio
        mientras no-junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                norte;
                repetir x veces avanza;
                oeste;
                avanza;
                sur;
            fin;
        fin;
        corre;
        norte;
        repetir x veces avanza;
        este;
        avanza;
        deja-zumbador;
        oeste;
        avanza;
        mientras no-junto-a-zumbador hacer avanza;
        agarra(0);
    fin;
    define-nueva-instruccion ir-ultimo(x) como inicio
        si no-junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                ir-ultimo(x);
            fin sino inicio
                oeste;
                corre;
                sur;
                avanza;
                este;
                ir-ultimo(precede(x));
            fin;
        fin sino inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                corre;
                sur;
                ir-final(x);
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta(x) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta(sucede(x));
        fin sino inicio
            este;
            ir-ultimo(x);
        fin;
    fin;
    inicia-ejecucion
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
