iniciar-programa
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion amplia(x) como inicio
    gira(1);
    repetir x veces avanza;
    gira(3);
    repetir x veces inicio
        deja-zumbador;
        repetir x veces inicio
            avanza;
            deja-zumbador;
        fin;
        gira(3);
        avanza;
        gira(3);
        repetir x veces avanza;
        gira(2);
    fin;
    deja-zumbador;
    repetir x veces inicio
        avanza;
        deja-zumbador;
    fin;
    si frente-libre entonces avanza;
fin;
define-nueva-instruccion mover(x) como inicio
    repetir x veces inicio
        si frente-libre entonces avanza;
    fin;
    si frente-libre entonces avanza;
fin;
define-nueva-instruccion posicion(x) como inicio
    si junto-a-zumbador entonces inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces inicio
                posicion(x);
                amplia(x);
            fin sino inicio
                si junto-a-zumbador entonces inicio
                    posicion(x);
                    amplia(x);
                fin sino inicio
                    posicion(x);
                    mover(x);
                    amplia(x);
                fin;
            fin;
        fin sino inicio
            posicion(x);
            amplia(x);
        fin;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces inicio
                posicion(x);
                si frente-libre entonces mover(x);
            fin sino inicio
                si junto-a-zumbador entonces inicio
                    posicion(x);
                    si frente-libre entonces mover(x);
                fin sino inicio
                    posicion(x);
                    si frente-libre entonces mover(x);
                    si frente-libre entonces mover(x);
                fin;
            fin;
        fin sino inicio
            gira(1);
            si frente-libre entonces inicio
                avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                gira(2);
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                posicion(x);
                gira(1);
                repetir x veces avanza;
                si frente-libre entonces avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                gira(2);
            fin sino inicio
                gira(1);
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(x));
    fin sino inicio
        deja-zumbador;
        posicion(x);
    fin;
fin;
    inicia-ejecucion
    mientras frente-libre hacer avanza;
    gira(3);
    mientras frente-libre hacer avanza;
    gira(2);
    mientras no junto-a-zumbador hacer inicio
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        si no junto-a-zumbador entonces inicio
            gira(1);
            si frente-libre entonces inicio
                avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                gira(2);
                fin;
            fin;
        fin;
        si junto-a-zumbador entonces coge-zumbador;
    cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
