iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion buscar como inicio
    mientras no-junto-a-zumbador hacer inicio
        si frente-libre entonces avanza
        sino inicio
            gira-izquierda;
            si orientado-al-oeste entonces gira(2);
            si frente-libre entonces avanza
            sino apagate;
            gira-izquierda;
            si frente-bloqueado entonces gira(2);
        fin;
    fin;
fin;

define-nueva-instruccion ampliar-v(z) como inicio
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ampliar-v(z);
            repetir z veces inicio
                si frente-libre entonces avanza
                sino gira(2);
                deja-zumbador;
            fin;
        fin sino inicio
            ampliar-v(z);
            repetir z veces inicio
                si frente-libre entonces avanza
                sino inicio
                    si orientado-al-sur entonces gira(2)
                    sino inicio
                        si izquierda-libre entonces inicio
                            gira-izquierda;
                            avanza;
                            gira-izquierda;
                            ampliar-v(z);
                        fin sino apagate;
                    fin;
                fin;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion ampliar-h(z) como inicio
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces inicio
            repetir z veces coge-zumbador;
            ampliar-h(z);
            repetir z veces inicio
                si frente-libre entonces avanza
                sino gira(2);
                deja-zumbador;
            fin;
        fin sino inicio
            ampliar-h(z);
            repetir z veces inicio
                si frente-libre entonces avanza
                sino inicio
                    si orientado-al-oeste entonces gira(2)
                    sino inicio
                        si derecha-libre entonces inicio
                            gira(3);
                            avanza;
                            gira(3);
                            ampliar-h(z);
                        fin sino inicio
                            gira-izquierda;
                            mientras frente-libre hacer avanza;
                            gira(2);
                            ampliar-v(z);
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion contar(z) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        contar(sucede(z));
    fin sino inicio
        repetir z veces deja-zumbador;
        mientras no-orientado-al-este hacer gira-izquierda;
        repetir 2 veces inicio
            mientras frente-libre hacer avanza;
            gira-izquierda;
        fin;
        ampliar-h(z);
    fin;
fin;

    inicia-ejecucion
        buscar;
        coge-zumbador;
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            apagate;
        fin;
        contar(1);
    termina-ejecucion
finalizar-programa
